Multiple parsers at the same time

2019-12-30 02:07:04

With the latest master, being able to use multiple parsers in the same site can be achieved using the dependent-sum library. Using code like the following in the user Main.hs:

type SomeSource (srcType :: * -> *) = Source (DSum srcType Identity)

mkSomeSource :: srcType doc -> Source doc -> SomeSource srcType
mkSomeSource t = fmap (t ==>)

data SourceType :: * -> * where
  SourceType_Markdown :: SourceType MMark
  SourceType_Entry :: SourceType E.Entry

data Target
  = Target_Index [SomeSource SourceType]
  | Target_Page (SomeSource SourceType)

data MarkdownMeta
  = MarkdownMeta
      { title :: Text
      }
  deriving (Show, Eq, Generic, FromJSON)

main :: IO ()
main = Rib.run [reldir|a|] [reldir|b|] generateSite
  where
    -- Shake Action for generating the static site
    generateSite :: Action ()
    generateSite = do
      Rib.buildStaticFiles [[relfile|static/**|]]
      docs <-
        Rib.buildHtmlMulti [[relfile|*.md|]] M.parseIO $
          renderPage . Target_Page . mkSomeSource SourceType_Markdown
      entries <-
        Rib.buildHtmlMulti [[relfile|*/*/*.dhall|]] E.parseIO $
          renderPage . Target_Page . mkSomeSource SourceType_Entry
      Rib.buildHtml [relfile|index.html|]
        $ renderPage
        $ Target_Index
        $ mconcat
          [ mkSomeSource SourceType_Entry <$> reverse (sortOn Rib.sourcePath entries),
            mkSomeSource SourceType_Markdown <$> docs
          ]

2019-12-30 02:07:31

This examples shows how we have a static site of both MMark and Dhall sources!

2019-12-30 02:08:06

Rib used to have this SourceType type, which is what got removed in the latest PR, to allow the user some flexibility.

2019-12-30 02:08:33

So now dabbling with dependent-sum is the user's responsibility.

2019-12-30 02:09:06

(Technically you can use multiple parsers at the same without any of these machinary if your Target type had unique constructors for each parser type)

Multiple parsers at the same time - Rib