Dhall as a template engine - Dhall

let Person =
  { name : Text
  , age : Natural
  }
let Message =
  { recipient : Person
  , sender : Person
  , content : Text
  }

let Text/concatMapSep = https://prelude.dhall-lang.org/Text/concatMapSep sha256:c272aca80a607bc5963d1fcb38819e7e0d3e72ac4d02b1183b1afb6a91340840

let renderMessage : Message -> Text =
  \(message : Message) ->
  ''
  Message from ${message.sender.name}
  Sent to ${message.recipient.name}

  ${message.content}
  ''

let fun : List Message -> Text =
  Text/concatMapSep "----------------------" Message renderMessage
in

fun

{-# LANGUAGE DerivingVia #-}
{-# LANGUAGE DataKinds #-}
{-# LANGUAGE DeriveGeneric #-}
{-# LANGUAGE TypeOperators #-}
module Main where

import Dhall.Deriving
import GHC.Generics (Generic)
import Dhall (FromDhall(..), ToDhall(..), inputFile, auto)

import Data.Text (Text)
import qualified Data.Text.IO as T

import Numeric.Natural

data Person
  = Person { personName :: !Text
           , personAge :: !Natural
           }
  deriving (Show, Generic)
  deriving (FromDhall, ToDhall)
    via Codec (Field (CamelCase <<< DropPrefix "person")) Person

data Message
  = Message { messageRecipient :: !Person
            , messageSender :: !Person
            , messageContent :: !Text
            }
  deriving (Show, Generic)
  deriving (FromDhall, ToDhall)
    via Codec (Field (CamelCase <<< DropPrefix "message")) Message

main :: IO ()
main = do
  renderMessage <- inputFile auto "template.dhall"
  let recipient = Person "foo" 3
      sender = Person "bar" 3
  T.putStrLn . renderMessage $ [Message recipient sender "content of the message"]